PeppersGhost XXI

# theme: light

// Profile image for the character Robin Williams
VAR profileRobin = "\<img src=\"https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/4391497495_c64f53376d_c.jpg\"\ class=\"profPic\" > "

// Adds icon denoting a choice is unlocked with surliness
VAR choice_surly = "\<img src=\"https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/Test_Dummies.png\"\ class=\"picChoice\" > "

// Character variables

VAR nosy = 0
// Suspiciousness
VAR moxie = 0
// Superlativity
VAR psycho = 0
// Surliness
VAR suckup = 0
// Sycophancy 
VAR smarts = 0
// Smarts

VAR life = 3

//Event variables

VAR cigar_eye = false
// Has Villanova stuck a cigar in your eye?

VAR knows_dunlap = false
// either getmad or met_dunlap

VAR nickname = ""
// What did you call Mr. Peepers?
VAR nicknameS = false
// Does Peepers' nickname end in S?

 /*--------------------------------------------------------------------------------
for images:
# IMAGE: https:\/\/

To add CSS classes, append this to the end of the line: # CLASS: speech

--------------------------------------------------------------------------------*/

// DEBUG mode adds a few shortcuts - remember to set to false in release!
VAR DEBUG = true
{DEBUG:
    IN DEBUG MODE!
    *    [Prologue]    -> start
    *    [Pt. 1: Peepers] -> peepers_entrance
    *    [Experiments] -> test_knot
- else:
    // First diversion: where do we begin?
 -> start
}

 /*--------------------------------------------------------------------------------
    Wrap up character movement using functions, in case we want to develop this logic in future
--------------------------------------------------------------------------------*/

=== function lower(ref x)
     ~ x = x - 1

=== function raise(ref x)
     ~ x = x + 1

=== function raise2(ref x)
     ~ x = x + 2

/*
    Prints the correct form of the indefinite article before a noun.

    Usage: 

    VAR firstAnimal = "cat"
    VAR secondAnimal = "elephant"
    VAR thirdAnimal = "elongated badger"
    I put {a(firstAnimal)} and {a(secondAnimal)} into {a("{~old|nice} box")} with {a(thirdAnimal)}.

*/

=== function a(x)
    ~ temp stringWithStartMarker = "^" + x
    { stringWithStartMarker ? "^a" or stringWithStartMarker ? "^A" or stringWithStartMarker ? "^e" or  stringWithStartMarker ? "^E"  or stringWithStartMarker ? "^i" or stringWithStartMarker ? "^I"  or stringWithStartMarker ? "^o" or stringWithStartMarker ? "^O" or stringWithStartMarker ? "^u"  or stringWithStartMarker ? "^U"  :
            an {x}

    // this could be extended to check for "^hi" if you wanted "an historic..."            
    - else:
        a {x}
    }
/*
    Tests if the flow has reached one divert more recently than another.

    If we have never reached the first divert, we return false. 
    If we have never reached the second divert, we return true. 

    This is especially useful for testing "have we done X this scene".

    Usage: 

    - (start_of_scene)
        "Welcome!"

    - (opts)    
        <- cough_politely(-> opts)

        *    { seen_more_recently_than(-> cough_politely.cough, -> start_of_scene) }
            "Hello!"

        +    { not seen_more_recently_than(-> cough_politely.cough, -> start_of_scene) }
            ["Hello!"]
            I try to speak, but I can't get the words out!
            -> opts

    === cough_politely(-> go_to)
        *    (cough) [Cough politely]
            I clear my throat. 
            -> go_to

*/

=== function seen_more_recently_than(-> link, -> marker)
    { TURNS_SINCE(link) >= 0: 
        { TURNS_SINCE(marker) == -1: 
            ~ return true 
        } 
        ~ return TURNS_SINCE(link) < TURNS_SINCE(marker) 
    }
    ~ return false 

/*--------------------------------------------------------------------------------

    Start the story!

--------------------------------------------------------------------------------*/

=== test_knot === 
# IMAGE: https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/4391497495_c64f53376d_c.jpg 
# CLASS:prePic
{profileRobin}
"This is test dialogue." # CLASS:speech
# CLASS:prePic2
{profileRobin}
"This is test dialogue." # CLASS:speech
# CLASS:prePic3
\<img src="https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/4391497495_c64f53376d_c.jpg"\ class="profPic" > 
"This is test dialogue." # CLASS:speech
# CLASS:prePic
\<img src="https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/17252189465_8d18966896_c.jpg"\ class="profPic" > 
"Oh yeah? What kinda test dialogue we talkin' here? Some kind of long dialogue? Like really long? Like so long it challenges the very notion of how long a dialogue box can be? Maybe even taller than the portrait next to the dialogue? Or what if it just keeps going even longer, not really talking about anything other than how long it is? What about that? How you like them apples, ya big palooka?" <br><br> "And then what if I repeated myself from the beginning? Oh yeah? What kinda test dialogue we talkin' here? Some kind of long dialogue? Like really long? Like so long it challenges the very notion of how long a dialogue box can be? Maybe even taller than the portrait next to the dialogue? Or what if it just keeps going even longer, not really talking about anything other than how long it is? What about that? How you like them apples, ya big palooka?" # CLASS:speech
# CLASS:prePic
\<img src="https:\/\/scp-sandbox-3.wdfiles.com/local--files/peppersghost-xxi/4391497495_c64f53376d_c.jpg"\ class="profPic" > 
"Just regular test dialogue, numbskull!" # CLASS:speech
# CLASS:endProf
\<div class="testDiv"></div>
And then there was div

# PROFILE : 4391497495_c64f53376d_c.jpg #CLASS:profPic

* [ "This is a test, isnt it?" {choice_surly} ] 

-> start

=== start === 

// Intro
    -    They sit you down and pull the bag off your head.
        It's a small room. The air feels thin and musty, like you're a million miles underground. The only furnishings are the antique table and six seats around it. Judging by the bloodstained lacquer, the Chicago Spirit probably doesn't use this place for tea parties. 
        The walls are hewn stone. They're covered in some kind of writing, but it's too dark to make out the details. You also can't tell if it's written in blood, but given the circumstances, blood would be a safe bet.
        Your only sources of light are a smattering of candles set up haphazardly across the table and floor, and the faint glow of the burning cigars held by the four other people around the table. Their faces are obscured by the dark and the smoke and the long low brims of their fedoras.
        You suppress the urge to smile.
        This is exactly where you wanted to be. Where the Foundation wanted you to be. 
        You could do without the ropes around your wrists and ankles, though. 

    -    (beginning)
        {|The room is so quiet you could hear a pin drop. The smoke from so many candles and cigars is building to a bleary haze.|Time passes in silence. Your present company looks to be getting bored.|The silence hangs heavy and the cigar smoke hangs even heavier, clouding your thoughts and senses. Every now and then you'll get a whiff that fires a spark behind your eyelids and a jolt through your teeth. Whatever these guys are puffing ain't tobacco.|The candles are little more than glowing pools of wax at this point. You'll be in the dark soon.|}
        {!There's a few things you could do at this point. You can try them in any order. You don't have to try all of them. It's possible you <i>shouldn't</i> try all of them, and you may not even get the chance.}

        *     (remember) [Remember]
        ~ raise(smarts)
            Let's take it from the top.
            You're a Foundation mole who has been tasked with infiltrating the Chicago Spirit, an organized crime ring that leverages anomalies to expand its bootlegging empire. 
            It may not be very flattering to think about, but you play a convincing thug. Still, getting recruited by the Spirit is no easy feat. The very first step is getting noticed, and the tricky part there is that a guy has to make a big enough splash to grab the Spirit's attention, but not so big that he's seen as a liability.
            Judging by your current position, you definitely got their attention. Now it's just a question of whether you're about to be inducted into the little club or be fitted for a pair of cement shoes. Maybe they haven’t decided yet.
            If you put your mind to it, you may be able to recall a few things you've heard about these folks. 
            -> beginning
        +    {remember} [Identify] -> identify ->
        -> beginning
        *    (greet) [Greet]
            {
            -   not question && not threaten:"Good evening," you say, flipping your hair back with as much nonchalance as you can muster. "Name's Ezra Faulk—though I'm sure you all knew that already. I hope you'll forgive me being underdressed." 
                In truth, you'd feel under-dressed in this group even if you hadn't been stolen from your bed. You notice
                ~ raise(moxie)
            -     question && not threaten:"Maybe I'm getting ahead of myself," you say meekly. "Why don't we start over, introduce ourselves? My name is Ezra Faulk. You probably knew that already, considering you brought me here and all, but, well, there it is."
                Judging by the awkward silence, it’s a bit late for friendly first impressions. You smile and try to swallow the uncomfortable feeling in your throat, but quickly lower your gaze when it becomes clear that no one intends to acknowledge your presence.
                ~ raise(suckup)
                Looking down at the floor, you notice
                ~ raise(nosy)
            -     threaten:-> greet_threatened ->
                In the corner of your eye you can see
                ~ raise(psycho)
            }
            <> the flickering reflection of candlelight in the shiny leather shoes {getmad || identify.met_dunlap:Dunlap is wearing|worn by the man on your left}. Shoes that cost what you wouldn't earn in a year. One of those shoes is tapping the ground like he's counting the seconds. He doesn't seem to be paying you a lick of attention{threaten: anymore, though}.
            -> beginning
        *    (question) [Question]
            "You {psycho > 0:shitstains|fellas} care to tell me what {psycho > 0:the fuck }I'm doing here?"
            You get no response. 
            {identify.met_dunlap || getmad:Dunlap|The first man to your left} yawns and snuffs his cigar out on the table. It sizzles in a way that almost sounds like a fading scream, and the shadow of a smile flickers across his face. 
            He whips another cigar from nowhere in particular and lights his match with an uncomfortably prolonged strike. Like he's dragging it out to savor the sound.
            ~ raise(smarts)
            ~ raise(nosy)
            ~ raise(moxie)
            -> beginning
        *     (questionAgain) {question} [Question again]
            You cock your head{threaten: and sneer}. "Folks say the Spirits don't sleep, but you're looking like you want shuteye bad as I do. I must be moving up in the world if I'm worth so much of your time, right?"
            They don't take the bait. They just keep stewing in their inscrutable silence, either staring at you vague in judgement or occupying their eyeballs on a particularly interesting knot in the hardwood table. You're starting to think it's going to be like this the entire night. 
            ~ raise(nosy)
            ~ raise(moxie)
            * *    (pressed_luck) [Press your luck]
                ~ raise2(psycho)
                All this stonewalling must be making you antsy, because the words are out of your mouth before you realize they probably warranted further consideration:
                "If a high-dollar operation like the Spirit's gonna give a rat's cold dead ass about a guy like me, I must've either made your man Chappell real mad or real horny."
                {identify.met_dunlap:Dunlap|The shmuck on your left} nearly swallows his cig. The others take turns exchanging glances till finally one stands up. {identify.met_villanova:It's Villanova, the|The} one with the ruby set into the knot of his tie, the ruby that catches the candlelight to look like fire itself. 
                * * * [Try to react.]
                You can't react. There's nothing you can do.
                He's behind you. What comes next happens quickly, almost clinical in its expertise. A well-practiced thrust of his arm around your neck, your right eye peeled open by the same hand. The hot end of a cigar kisses your exposed eye deep and dirty, then comes back for seconds. Ash and embers smear across your face. 
                ~ cigar_eye = true
                No one says anything. No one needs to. Least of all you. A man gets hoarse with so much screaming.
                * * * *  [Keep quiet until something happens.]
                Every beat of your heart sends a throb of pain your skull. You can't see worth shit out of your right eye. You can barely stand to open it. 
                -> damage_taken ->
                Time ticks by, and you sit there in silence, ruminating on your wounded face and ego.
                -> peepers_entrance
            * *    [Don't press your luck]
                The idea crosses your mind to try saying something crass and taboo, but it only takes you two seconds to realize that would be very stupid. 
                -> beginning
        *    (threaten) [Threaten]
            "<>
            {
            - greet && not question:Not the type for pleasantries, I take it. Figures. Maybe you fucks would prefer the
            - question && not greet:Answer me, goddamn it! You fucks better enjoy the
            - greet && question:Well, no one can say I didn't try to do this politely. For your sake, you fellas better pray you enjoy the
            - else: I hope you gents are hungry for a
            }
            <> taste of your own ass, because after this little stunt, my boys are gonna cram your heads straight up your sphincters, and when that's done, they'll chop off your limbs and let the neighborhood kids trundle your hooped corpses up and down Michigan Avenue with a stick."
            It's a bluff, of course. None of your 'boys' are worth a wooden nickel in a fight. 
            You suspect {identify.met_hunt:Splinterfingers|the gal on your right} sees through you, given the timbre of his chuckle. It's not the kind of laugh a man makes when he hears something especially funny. It's the kind he spits out on purpose to tell someone they're full of shit.
            ~ raise(psycho)
            -> beginning
        *    (getmad) {threaten} [Get mad]
            ~ raise(psycho)
            ~ raise(moxie)
            {
            - question && not identify.met_dunlap:The smoker on your left is still playing with his matches.
            - identify.met_dunlap: That mook Dunlap is still playing with his matches.
            - else:The guy on your left is playing with matches, presumably out of boredom.
            }

            <> Gives 'em a slow drag across the table, punctuates it with a flick of the wrist at the end, then watches them burn down to his fingertips. 
            {identify.met_dunlap:<>|Even with the low brim of his fedora stooped over his beady eyes, the small shimmer of match light is all you need to confirm that it's Rufus Dunlap. Kid's jaw sticks out so far you'd think it was gearing to jump off his face.} His eyes are even more glazed than usual, and he tips his chair up on its rear legs so he can prop his feet on the table.
            ~ knows_dunlap = true
            You can see your reflection in his shiny shoes. You realize you look mad. You're real mad. These ropes are chafing you, nobody's talking, you're sweating up a storm because there's no goddamn air in this place, and all of it feels worse by twice at the sight of Rufus Dunlap making himself cozy. 
            * * [Show him how mad you are.]
            {greet_threatened:"Won't even tell me how you're doing, huh?" you ask, smiling through gritted teeth. "Well, I'm doing fucking dandy!"}
            With a touch more effort than you'd like to admit, you kick your legs up and slam the underside of the table. It's a heavy old beast that probably wouldn't flip over for a hurricane, but you still rattle it enough to knock Dunlap off balance. In a flash he's scrabbling on the floor, slapping at spots where the candles singed his fancy suit. 
            The other three just laugh. That's the sort of place Dunlap has with this bunch. 
            You feel a little better. 
            -> beginning
        *    [Wait]
            You decide to ride out the silence and wait for something to happen. <>
            -> peepers_entrance

= greet_threatened 

    "So how's everybody doin' tonight?" you ask nonchalantly. "Good day at work? Enjoyin' the weather? Name's Ezra Faulk, by the way. Not sure I mentioned that."
    You get some odd looks, given your earlier outburst, but nobody says anything. {getmad:Dunlap just sulks. He's not even playing with his matches anymore.}
    ->->

=== damage_taken
    ~ lower(life)
    {!All things considered, you got off easy. You should probably tread more carefully from here out.|Things definitely aren't going as well as they could have. You'll have to play your cards carefully if you want to make it out of this alive.|The situation's grim. If you give them one more reason to hate you, you're as good as dead.}
    {life > 0:->->| -> death_scene} 

=== death_scene ===
Oops. You died.
-> END

=== identify ===
            You take {a good|another} look at the four unfriendly faces around the table.
            {met_dunlap:First on your left is good ol' Rufus Dunlap, looking young, dim, and punchable.} 
            {met_bookman:Second on your left is Bookman. You still feel his gaze whenever you're not looking directly at him. }
            {met_villanova:Second on your right is Vincenzo Villanova. There's a gleam in his eyes almost as bright as the gem in his necktie.}
            {met_hunt:Oliver J. Hunt sits to your right. Old Splinterfingers, in the flesh. Mostly..}
            {fifth_chair:The chair between Villanova and Hunt is empty. It's also conspicuously larger than the other chairs.}
            {not met_dunlap&&not met_bookman&&not met_villanova&&not met_hunt&&not fifth_chair:Geez, where to start with these clowns? | {not met_dunlap||not met_bookman||not met_villanova||not met_hunt||not fifth_chair:Who do you take a closer look at?|->->} }
            * *    (met_dunlap) [The slack-jawed one.]
            {
            - start.getmad:First on your left is good ol' Rufus Dunlap, still rattled from his earlier tumble. The twerp's sweating a bit now, which is gratifying since you're the one who’s supposed to be in the hot seat. 
            He's not a pretty one, Dunlap. <>
            - not start.getmad:You take a look at the slack-jawed one sitting to your left, playing with matches. 
            Even with the tattered brim of his fedora stooped over his eyes, the sliver of light from his matchstick is all you need to confirm that it's Rufus Dunlap. <>
            }
            The kid's jaw isn't just slack, it sticks out so far you'd think it was gearing to jump off his face. 
            ~ knows_dunlap = true
            You've heard stories about the kind of knuckleheaded fuckups Dunlap's known for, but nobody's ever given you a solid answer as to how a dolt like him managed to get in good with the Spirit in the first place. A decent gimmick can cover a multitude of shortcomings, though. 
            You don't know what Rufus Dunlap's gimmick is, but you assume it must be a hell of a whopper.
            -> identified
            * *    (met_bookman) [The guy with the stare.]
                Second on your left is a quiet man. Not timid. Just quiet. He's the type that says nothing and hears everything. There's an uncanny alertness to his posture, his gaze. Like he's taking in every detail of every second. 
                Whenever you start to look away from him and he drifts to the corner of your eye, there's a moment you would swear he was staring straight at you with that sharp, icy glare of his. Naturally, the instant you focus your sights back on him, he's facing somewhere else.
                It strikes you that he's a much darker shade than the others. The Spirit, contrary to many of its peers, doesn't care so much where a man comes from as it does about what he brings to the table. 
                You wrack your brain. You heard a story one time about a guy named Bookman that plays lookout during high-profile Spirit activities. The gentleman on your left perfectly fits the description they gave.
                You're not sure what Bookman's gimmick is, but he's probably got one. You bet it has something to do with how he always seems to be looking in every direction at the same time, even though he's not. That ain't normal.
                -> identified
            * *    (met_villanova) [The fellow in the fancy necktie.]
                The fellow on your second right is easy enough to recognize. There's a shiny red gemstone folded into the knot of his tie, reflecting the candlelight in a way that almost seems to amplify it, casting a delicate crimson glow along the edges of his features.
                -> villanova_description ->
                Hearsay aside, Villanova's prettyboy face doesn't exactly strike fear into your heart. The most unsettling thing about him is that tiny hint of a smile that never quite leaves his face. That, and the strange, shiny gem in his tie. Is the light coming off it pulsing in time to your heartbeat…?
                Nah. It’s probably your imagination.
                -> identified
            * *    (met_hunt) [The one in leather gloves.]
                Olivia J. Hunt sits to your right. Old Splinterfingers herself. The hands were a dead giveaway, even with those fancy leather gloves on 'em. You can tell by the way she holds her cigar that they're too stiff to be flesh. Hands like a fancy mannequin. 
                Not that you're judging her. Hell, if a person's going to have mannequin hands, might as well spring for the fancy ones.
                Hunt's a crackerjack lock picker from what you've heard, though that kind of grunt work is long behind her these days. Folks in the business call her a grizzled veteran, though looking at her now, you only see a couple small streaks of gray in her hair. It's sad what passes for an old-timer in the underworld. 
                They say the reason she's so good at picking locks is thanks to what else she’s got in the places where he her hands don’t go. You have no idea what that means. You'd rather not find out the hard way.
                -> identified
            + + {not met_dunlap || not met_bookman || not met_villanova || not met_hunt} [Never mind.]
                       ->->
            * *  (fifth_chair) {met_dunlap && met_bookman && met_villanova && met_hunt} [The fifth chair.]
                ~ raise(smarts)
                The chair between Villanova and Hunt—the one directly across from you—is empty. It's also conspicuously larger than the other chairs.
                ->->

            * *    ->->

= identified
+ [Look at the other people at the table.]
-> identify
+ [Do something else.]
-> start.beginning

= villanova_description
Vincenzo Villanova. Young and hungry. Ex-mafioso, which is rare in the Spirit. Those inclined to jump ship aren't exactly renowned for their loyalty, and they're rarely worth the effort it takes to keep 'em out of the family's vengeful hands. 
Chappell's taken a shine to this one, though. Stories have been going around about Villanova's own capo taking out a contract on him, only for the hitman to end up dead instead. How he died changes every time the story's told, but it's always extravagantly gruesome.
{ cigar_eye: Given that the man put his cig out on your eyeball like it was a Sunday afternoon chore, you're inclined to think the stories might not be such an exaggeration. }
->->

=== peepers_entrance===
= door_burst
    { cigar_eye:All of a sudden|Just when you start to feel like nodding off,} there's a crash at the other end of the room. The old wooden door flies open and bounces off the wall like it's fixing to leap off its hinges.
    "Finally!" {identify.met_hunt:Splinterfingers|The woman to your right} mutters to herself. Judging by their expressions, the other men at the table share the sentiment. 
    There's a jaunty man in the doorway, and he's holding his boot in the air a tick longer than he needs to. Like he wants to make certain everyone knows he kicked his way in.
    Fella's draped in one of those billowing raccoon coats like all the college-going boys wear these days, but his sunken cheeks and distant hairline indicate that a college boy he is not. Or if he is, he’s crammed a lot of hard living into a remarkably short span of time.
    "Brothers!" he exclaims. "As of tonight, I can now say with god as my witness that I have slept with every last whore the good city of Chicago has to offer."
    *   (peepers_mock) [Mock]
            ~ raise(psycho)
            { psycho > 1:"You slept with your own mother?" you ask.|"Must be pretty easy when it only takes you a minute each," you say.}
                -> meet_peepers -> peepers_ha -> 
                Quick wit! Brass balls! 
    *   (peepers_congrats) [Congratulate]
            ~ raise(moxie)
            "That's an impressive feat," you tell him earnestly. "Well done."
            -> meet_peepers ->
            "Thank you!" he says, grinning. "At least one man here knows when he's presented with a momentous accomplishment. The rest of you ought to take note."
            {identify.met_dunlap || start.getmad:Dunlap|The guy in the shiny shoes} tentatively applauds, but none of the others follow suit. 
                -> peepers_ha ->
                Courtesy! Respect! 
    *   (peepers_wtf) "What the fuck[..."] is going on here?" you yell. 
            ~ raise(psycho)
            -> meet_peepers -> peepers_ha -> 
            Straight to the point! No bullshit! 
    *   (peepers_quiet) [Keep quiet]
            ~ lower(moxie)
            You're not sure what to say, or even if you should say anything at all. The others at the table seem to be having similar thoughts. -> meet_peepers ->
            "Whatever you're gonna be, be the best," {identify.met_villanova:Villanova|the man in the fancy tie} finally says. "That's what Noni always said."
            "You better be shitting me," seethes {identify.met_hunt:Hunt|the woman on your right}. "You really made us wait here all night while you were out getting your pecker wet?"
            Grinning, the gent with the guns for eyes makes his way around the table and claps his hands against your shoulders, giving you a friendly jostle.{cigar_eye: Your head hurts like hell.}
            "Yes!" he says. "I'm pleased you didn't start the festivities without me. My associates have been keeping you nice and comfortable, yes?"
            He leans down real close to your face until you can feel the cool metal of his eye-barrels against your temple.
            * *    "Cozy as a kitten[." (Sycophantic)]," you say.
            ~ raise(suckup)
                -> peepers_ha ->
                He knows his place! Shows respect when it’s due!
            * *    "I've had better hospitality[..." (Saucy)] in federal prisons," you say.
            ~ raise(moxie)
                -> peepers_ha ->
                He speaks his mind! No fear whatsoever!
        - <> { cigar_eye:You may look like shit, kid, but you've got q|Q}ualities that the Chicago Spirit is in desperate need of these days."
        -> peepers_intro

= meet_peepers
// Tunnel
The stranger looks at you. Staring into his eyes is like staring down the barrel of a gun. Two guns, actually, since there are literally two gun barrels jutting from the holes in his face where his eyes should be. 
->->

= peepers_ha
// Tunnel
"Ha!" he says. It's more of a bark than a laugh. "I like this one!{peepers_quiet: |"}
{peepers_congrats: He's pointing at you as he says that. }{peepers_quiet:<> |The gent with the guns for eyes makes his way over and claps his hands against your shoulders, giving you a friendly jostle.{cigar_eye: Your head hurts like hell.}}
{peepers_quiet: |"<>}
->->

= peepers_intro
The strange man swing around your left, sliding himself between you and {knows_dunlap:Dunlap|the slack-jawed guy at the table}. He's leaning back all relaxed-like, with his chin on his palm and a million-dollar grin on his face.
"My name is Harvey Goodwill," he says, "but only the law calls me that. To my friends, I'm simply Harv. And to those who fear me, I am known as Mr. Peepers."
Flecks of dancing candlelight reflect off the smooth metal barrels protruding from his head. { smarts > 1:This is a test. } 
{smarts > 0: The others around the table are looking at you as well. They're waiting to see how you react.}

* "Mr. Goodwill. It's a pleasure."
    ~ raise(nosy)
    ~ nickname = "Mr. Goodwill"
    As you speak, {nickname}'s grin broadens. {smarts > 0:You interest him.} Not everyone else at the table looks as happy, though.

* (called_peepers) "Nice to meet you, Mr. Peepers."
    ~ raise(suckup)
    ~ raise(smarts)
    ~ nickname = "Mr. Peepers"
    ~ nicknameS = true
    Someone at the table chuckles, but you can't tell who. 
    Mr. Peepers stands up from the table and gives your shoulder another too-tight-to-be-friendly squeeze. 
    "Good answer," he whispers in your ear. You feel an chill radiating off his eye-barrels as he leans in close.  

* "Howdy, Harv!"
    ~ nickname = "Harv"
    ~ raise(moxie)
    You say it brightly, like you're greeting an old pal. Harv's grin broadens. {smarts > 0:You interest him.} 

* { psycho > 1 || moxie > 1 } "I think I'll call you Twinkletoes[." (UNLOCKED)]," you reply. 
    ~ nickname = "Twinkletoes"
    ~ nicknameS = true
    ~ raise(psycho)
    ~ raise(moxie)
    The man's posture straightens, his head off his palm. Guess he wasn't expecting that.
    "Oooh!" exclaims Twinkletoes. "You{peepers_mock||peepers_wtf: really are|'re a} mouthy one, aren't you? Ha! I love it!"

* { psycho > 3 } "Hey, bitch[." (UNLOCKED)]," you say, practically spitting the words at him.
    ~ nickname = "The Bitch"
    {start.getmad: Dunlap nearly falls out of his chair a second time.} 
    It's a bold move on your part. You're not sure it'll pay off, but you also don't really care whether it does. Rich, red blood is coursing through your veins. You're having fun. {cigar_eye:Even the burning in your eye hurts a little less now.} 

* "My name's Ezra Faulk[."]," you tell him.

    Mr. Peepers leans in and pats you softly on the shoulder. The way you'd pat a puppy dog.

    "I know," he says gently. 
* {cigar_eye} [Tell him what happened to your eye.]
    "Your man over there started the party without you," you say, nodding to the asshole who burned you. "Gave me a little souvenier. Guess he couldn't help himself."
    Mr. Peepers' barrel-eyes are on the man in an instant.
    "That true, Vinnie?" asks Mr. Peepers. He isn't grinning anymore.
    The name 'Vinnie' rings a bell. You look at the guy in the fancy necktie, and then it hits you.
    Vincenzo Villanova. Young and hungry. Ex-mafioso, which is rare in the Spirit. Those inclined to jump ship aren't exactly renowned for their loyalty, and they're rarely worth the effort it takes to keep 'em out of the family's vengeful hands.
    Chappell's taken a shine to this one, though. Stories have been going around about Villanova's own capo taking out a contract on him, only for the hitman to end up dead instead. How he died changes every time the story's told, but it's always extravagantly gruesome.
    Given that the man put his cig out on your eyeball like it was a Sunday afternoon chore, you're inclined to think the stories might not be such an exaggeration.
    "He disrespected Chappell," Villanova replies. It's simple a statement of fact.
    His tone is firm and he holds an even gaze with Mr. Peepers 'eyes.' You figure it's probably not Vinnie's first time staring down the barrel of a gun.
    "And you disrespected me by disobeying my instructions!" Mr. Peepers chides.
Villanova makes a face like he's fixing to talk back, but then leans back, shaking his head. He gives his hands a dismissive flip, the way a guy does when he folds during poker.
    "Sorry, sir," he says. There's no sarcasm behind that 'sir,' but there's no real effort either.
    "You boys done?" asks the lady to your right, her voice weary.
Mr. Peepers adjusts his coat and puts his grin back on.
    "Oh, we're just getting started," he tells her.

* Say Nothing.

- {nickname}{nicknameS:'|'s}

-> END
SCP Sandbox III

Sandbox III: Revenge of the Sandbox
